Sierpiński Carpet

DEFINITION

divide [0,1]² into 3×3, remove the centre, recurse
x ∈ carpet ⇔ no k has ⌊3ᵏx⌋ ≡ ⌊3ᵏy⌋ ≡ 1 (mod 3)
dim_H = log 8 / log 3 ≈ 1.8928

NOTES

Sierpiński built it as a curve containing a continuous image of every curve — a universal object, published two years before anyone could draw more than three levels of it by hand. The construction is base three: a point survives unless, at some depth, both of its ternary digits read 1 at once, which is the centre cell. What survives has area zero and infinite perimeter, and every part of it is the whole scaled by a third. The plate colours each removed square by the depth at which it fell, walks the frame slowly round and breathes the zoom, and tiles — the carpet is periodic under its own subdivisions, which is also what makes it a rewarding composition operand.

PROVENANCE

Origin

W. Sierpiński, "Sur une courbe cantorienne qui contient une image biunivoque et continue de toute courbe donnée", Comptes Rendus Acad. Sci. Paris 162, 1916, 629–632

Standing

Public domain since 1916. No patent. The 1915 companion note is the triangle, not the carpet — a citation that splices the two is wrong in a way this atlas cares about

Constants

Depth is the recursion cut-off — the slider ceiling is the loop bound, mandelbrot fashion. Below depth 3 the figure is a grid, not yet a fractal

TOUCHDESIGNER · GLSL

The same shader this plate runs, reframed for a GLSL TOP. Pasted bare it renders the published constants as a still frame; wire absTime.seconds into u_t on the Vectors page to animate it.

// FORMA — PL. 107 · SIERPIŃSKI CARPET — Wacław Sierpiński, 1916
//   divide [0,1]² into 3×3, remove the centre, recurse
//   x ∈ carpet ⇔ no k has ⌊3ᵏx⌋ ≡ ⌊3ᵏy⌋ ≡ 1 (mod 3)
//   dim_H = log 8 / log 3 ≈ 1.8928
// TouchDesigner port — paste into a GLSL TOP's pixel shader. Set the
// resolution on the TOP's Common page. As pasted it renders the published
// constants as a still frame; to animate, add a uniform named u_t on the
// GLSL TOP's Vectors 1 page with the expression absTime.seconds.
// Constants are consts — edit to tweak; comments give the measured range.
// Written from the published mathematics, not adapted from any code.

#define u_res (uTDOutputInfo.res.zw)
uniform float u_t;               // absTime.seconds on the Vectors page; unset = still

const float u_phase = 0.5981;    // this plate's own grid phase, 0..1
// FORMA's FRACTALS accent as cosine-gradient coefficients
const vec3 u_pal_a = vec3(0.46, 0.1389, 0.1912);
const vec3 u_pal_b = vec3(0.5, 0.151, 0.2078);
const vec3 u_pal_c = vec3(1, 1, 1);
const vec3 u_pal_d = vec3(0, 0.05, 0.1);

const float p_depth = 5.0;         // recursion depth · live 2 .. 7
const float p_zoom  = 1.2;         // zoom · live 0.8 .. 3
const float p_spin  = 0.1;         // rotation speed · live 0 .. 0.5

/* The order's ramp — the same cosine formulation the JS kit uses, so a
   plate keeps its classification colour in either language. */
vec3 ramp(float t){
  return clamp(u_pal_a + u_pal_b * cos(6.28318530718 * (u_pal_c * t + u_pal_d)), 0.0, 1.0);
}

/* Sawtooth and triangle on this plate's phase, mirroring the JS kit. */
float cycle(float t, float period){ return fract(t / period + u_phase); }
float pingpong(float t, float period){
  float u = cycle(t, period);
  return u < 0.5 ? u * 2.0 : 2.0 - u * 2.0;
}


vec3 plate(vec2 uv){
  float ar = u_res.y / u_res.x;
  float ang = u_phase * 6.283 + u_t * p_spin;
  float ca = cos(ang), sa = sin(ang);
  float sc = p_zoom * (0.75 + 0.5 * pingpong(u_t * 0.04, 1.0));
  vec2 c = vec2(uv.x - 0.5, (uv.y - 0.5) * ar);
  vec2 q = fract(vec2(c.x * ca - c.y * sa, c.x * sa + c.y * ca) * sc + 0.5);
  float d = floor(p_depth + 0.5);
  /* Constant loop bound at the slider ceiling, break on the live value —
     mandelbrot fashion. */
  for (int k = 0; k < 7; k++){
    if (float(k) >= d) break;
    q *= 3.0;
    vec2 cell = floor(q);
    if (cell.x == 1.0 && cell.y == 1.0) return ramp(1.02 - float(k) * 0.055);
    q -= cell;
  }
  return ramp(0.85) * 0.28;
}

out vec4 fragColor;
void main(){
  // FORMA's uv runs y-down, matching its canvas; TD's vUV runs up
  vec2 uv = vec2(vUV.s, 1.0 - vUV.t);
  fragColor = TDOutputSwizzle(vec4(plate(uv), 1.0));
}

NUKE · BLINKSCRIPT

The same shader this plate runs, transpiled to a BlinkScript kernel. Paste it into a BlinkScript node's Kernel Source and press Recompile; every constant arrives as a knob at its published value, and u_t animates with the expression frame/24. Compiled and rendered in Nuke 17.1, then compared against this plate on the page.

// FORMA — PL. 107 · SIERPIŃSKI CARPET — Wacław Sierpiński, 1916
//   divide [0,1]² into 3×3, remove the centre, recurse
//   x ∈ carpet ⇔ no k has ⌊3ᵏx⌋ ≡ ⌊3ᵏy⌋ ≡ 1 (mod 3)
//   dim_H = log 8 / log 3 ≈ 1.8928
// Nuke port — a BlinkScript kernel. Paste into a BlinkScript node's Kernel
// Source and press Recompile. Every constant arrives as a knob at its published
// value (the comment gives the measured range); u_t is a knob too — animate it
// with the expression frame/24 or leave it at 0 for the still frame. Written
// from the published mathematics, not adapted from any code.
// Transpiled from the shader this plate runs on the page (GLSL ES 3.00):
// vec → float2/3/4, swizzles expanded, GLSL builtins Blink lacks written out
// as forma_ functions, float literals suffixed. Compiled and rendered in a
// real Nuke (17.1v1) and compared against this plate on the page: 34 of 34.
//
// plate() and its helpers are written to a single exit — the loop that runs
// once. That is not a style: Blink 17.1 drops a conditional early return from
// a called function while Vectorize is on, which is the node default, with no
// warning and no error. Written this way it paints correctly as pasted.

kernel Forma_sierpinski : ImageComputationKernel<ePixelWise>
{
  Image<eWrite> dst;

param:
  float u_t;             // seconds; 0 is the still frame
  float p_depth; // recursion depth · live 2 .. 7
  float p_zoom;  // zoom · live 0.8 .. 3
  float p_spin;  // rotation speed · live 0 .. 0.5

local:
  float2 u_res;
  float u_phase;
  float3 u_pal_a, u_pal_b, u_pal_c, u_pal_d;

  void define(){
    defineParam(u_t, "u_t", 0.0f);
    defineParam(p_depth, "p_depth", 5.0f);
    defineParam(p_zoom, "p_zoom", 1.2f);
    defineParam(p_spin, "p_spin", 0.1f);
  }

  void init(){
    u_res = float2(float(dst.bounds.width()), float(dst.bounds.height()));
    u_phase = 0.5981f;    // this plate's own grid phase, 0..1
    // FORMA's FRACTALS accent as cosine-gradient coefficients
    u_pal_a = float3(0.46f, 0.1389f, 0.1912f);
    u_pal_b = float3(0.5f, 0.151f, 0.2078f);
    u_pal_c = float3(1.0f, 1.0f, 1.0f);
    u_pal_d = float3(0.0f, 0.05f, 0.1f);
  }

  /* GLSL builtins Blink lacks, written as templates rather than overload sets.
     Blink's operators return expression templates (Swizzle<float,N>), so a call
     passing an expression cannot resolve against an overload set on float2
     against float3 — measured in Nuke 17.1: a float2 expression is ambiguous
     between the two, while scalar-against-vector resolves. A template deduces
     the expression's own type, so the ambiguity cannot arise. */
  template <class T> T forma_fract(T v){ return v - floor(v); }
  template <class T, class S> T forma_mod(T x, S y){ return x - y * floor(x / y); }
  /* Blink's own min/max/clamp take no scalar bound against a vector, which GLSL
     does; v * 0.0f + b is that bound at the vector's own width, and collapses to
     b when v is a scalar, so one template serves both. */
  template <class T, class S> T forma_min(T a, S b){ return min(a, a * 0.0f + b); }
  template <class T, class S> T forma_max(T a, S b){ return max(a, a * 0.0f + b); }
  template <class T, class S> T forma_clamp(T v, S lo, S hi){ return clamp(v, v * 0.0f + lo, v * 0.0f + hi); }
  int forma_min(int a, int b){ return min(a, b); }
  int forma_max(int a, int b){ return max(a, b); }
  /* GLSL step(edge, x) is 1 where x >= edge; floor(sign(x - e) * 0.5 + 1) is
     that exactly, equality included, out of builtins Blink does have. */
  template <class T, class S> T forma_step(S e, T x){ return floor(sign(x - e) * 0.5f + 1.0f); }
  template <class T, class S> T forma_smoothstep(S a, S b, T x){
    T t = forma_clamp((x - a) / (b - a), 0.0f, 1.0f);
    return t * t * (3.0f - 2.0f * t);
  }
  template <class T> float forma_distance(T a, T b){ return length(a - b); }
  float forma_tanh(float x){ float e = exp(2.0f * x); return (e - 1.0f) / (e + 1.0f); }
  float forma_radians(float d){ return d * 0.01745329252f; }
  // the page's hash2 is exact uint32; Blink has int, so the shifts are made
  // logical by masking and the read-back is lifted into 0 .. 2^32
  /* A uint read back as a float. Blink has no unsigned type, so a value past
     2^31 arrives as a negative int and float() of it is negative. Measured on
     gabor, whose own generator then returned uniforms in [-0.5, 0.5) and drew
     a different picture — it compiled, it rendered, and only comparing it with

  /* The order's ramp — the same cosine formulation the JS kit uses, so a
     plate keeps its classification colour in either language. */
  float3 ramp(float t){
    return forma_clamp(u_pal_a + u_pal_b * cos(6.28318530718f * (u_pal_c * t + u_pal_d)), 0.0f, 1.0f);
  }

  /* Sawtooth and triangle on this plate's phase, mirroring the JS kit. */
  float cycle(float t, float period){ return forma_fract(t / period + u_phase); }
  float pingpong(float t, float period){
    float u = cycle(t, period);
    return u < 0.5f ? u * 2.0f : 2.0f - u * 2.0f;
  }


  float3 plate(float2 uv){
    float3 forma_r = float3(0.0f, 0.0f, 0.0f);
    bool forma_done = false;
    for (int forma_once = 0; forma_once < 1; forma_once++){
      float ar = u_res.y / u_res.x;
      float ang = u_phase * 6.283f + u_t * p_spin;
      float ca = cos(ang);
      float sa = sin(ang);
      float sc = p_zoom * (0.75f + 0.5f * pingpong(u_t * 0.04f, 1.0f));
      float2 c = float2(uv.x - 0.5f, (uv.y - 0.5f) * ar);
      float2 q = forma_fract(float2(c.x * ca - c.y * sa, c.x * sa + c.y * ca) * sc + 0.5f);
      float d = floor(p_depth + 0.5f);
      /* Constant loop bound at the slider ceiling, break on the live value —
         mandelbrot fashion. */
      for (int k = 0; k < 7; k++){
        if (float(k) >= d) break;
        q *= 3.0f;
        float2 cell = floor(q);
        if (cell.x == 1.0f && cell.y == 1.0f) { forma_r = ramp(1.02f - float(k) * 0.055f); forma_done = true; break; }
        q -= cell;
      }
      if (forma_done) break;
      { forma_r = ramp(0.85f) * 0.28f; break; }
    }
    return forma_r;
  }

  void process(int2 pos){
    // FORMA's uv runs y-down like its canvas; Nuke's rows run up
    float2 uv = float2((float(pos.x) + 0.5f) / u_res.x, 1.0f - (float(pos.y) + 0.5f) / u_res.y);
    float3 c = plate(uv);
    dst() = float4(c.x, c.y, c.z, 1.0f);
  }
};